' V3 : Horloge 2D...
' Tracage à l'ancienne sans voxels
' Et usage exclusif de la trigonométrie :)

background #008

' ratio 16/9ème
?l = 40
?h = ?l * 16 / 9

' rien à préparer, on boucle :
do
	
	' en 2D il n'y a pas d'objets à l'écran mais que
	' du dessin : on commencer par effacer le précédent
	clear screen
	
	' la cadrant : un petit point pour chaque heure
	color #678
	trace size 1
	for 1 to 12 as ?hour
		?angle = ?hour * 360 / 12
		?x = ?l * (sin ?angle)
		?y = ?h * (cos ?angle)
		
		color #fff
		trace dot ?x, ?y
		
		' on peut également afficher le nombre...
		color #08f
		trace text ?hour center ?x * 1.1, ?y * 1.1
	next
	
	' Un rond central
	color #fff
	trace size 2
	trace dot 0, 0
	
	' L'aiguille des heures (rayon/2)
	trace size 3
	?x = ?l * (sin (hours) * 30)
	?y = ?h * (cos (hours) * 30)
	trace size 3
	trace line ?x / 2, ?y / 2 to 0, 0
	
	' L'aiguille des minutes
	trace size 2
	?x = ?l * (sin (minutes) * 6)
	?y = ?h * (cos (minutes) * 6)
	trace line ?x, ?y to 0, 0
	
	' L'aiguille des secondes
	trace size 1
	color #8f8
	?x = ?l * (sin (seconds) * 6)
	?y = ?h * (cos (seconds) * 6)
	trace line ?x, ?y to 0, 0
	
	' C'est prêt !
	wait 1
loop