' V2 : on va ajouter une "trotteuse" pour les secondes
' idée : on pourrait ajouter une seconde série de points
' plus sombres (color 45) pour donner l'impression de leds allumée/éteintes
background 45
color 5

' Création de 60 points : un pour chaque seconde.
' On ne rendra visible que le nombre correspondant
for 0 to 59 as ?secondes
	create sprite 1 as "s-?secondes"
	add "s-?secondes" dot 1, 1, 1
	
	' 60 x 6 = 360°
	' On va placer ces points sur un cercle trigo simple
	?angle = ?secondes * 6
	move "s-?secondes" to 20 * (sin ?angle), 20 * (cos ?angle), 0
	' et les orienter vers le centre
	turn z "s-?secondes" to -?angle
	' mise à jour inutile, mais juste pour voir leur creation
	update
next

' et la boucle principale...
do
	
	' Heure digiale : même principe que la V1
	?minutes = format zero (minutes) to 2
	?heures = format zero (hours) to 2
	
	if (even (seconds)) = 1
		?heure = ?heures + " " + ?minutes
	else
		?heure = ?heures + ":" + ?minutes
	end
	
	create text ?heure as "horloge"
	
	' mais on ne va afficher que N points
	' selon les secondes
	for 0 to 59 as ?secondes
		if ?secondes > (seconds)
			hide "s-?secondes"
		else
			show "s-?secondes"
		end
	next
	
	wait 1
	
loop